home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.A.po / FEATURES:BEAGLE / ALPHA.PLOT.SHK / ALPHA.PLOT / PICTURE BLOAD DEMO.bas < prev    next >
BASIC Source File  |  2000-01-01  |  3KB  |  40 lines
  1. 5  REM TYPE "RUN 5000" TO SEE BBROS LOGO UNSCRUNCHED. LIST 5000- TO SEE HOW IT WAS DONE.
  2. 9  REM <CTRL-J><CTRL-J>PICTURE BLOAD DEMO<CTRL-J>
  3. 10  ONERR  GOTO 1000: REM (GOTO 1000 WHEN CTRL-C IS TYPED)
  4. 20  REM <CTRL-J><CTRL-J>CLEAR & PRINT TEXT<CTRL-J>
  5. 30  TEXT : PRINT  CHR$(12): HOME : VTAB 12: REM (CLEARS TEXT SCREEN)
  6. 40  VTAB 12: HTAB 7: INVERSE : PRINT " THIS IS THE TEXT SCREEN."
  7. 50  PRINT : NORMAL : HTAB 10: PRINT "(CONTROL-C TO STOP.)": GOSUB 160
  8. 55  REM <CTRL-J><CTRL-J>CLEAR & LOAD PG.1 PIC<CTRL-J>
  9. 60  HGR : REM (REVEALS & CLEARS PAGE 1)
  10. 70  PRINT  CHR$(4);"BLOAD USER-FRIENDLY?,A$2000": REM  (LOADS PICTURE INTO PAGE 1)
  11. 75  REM <CTRL-J><CTRL-J>CLEAR & LOAD PG.2 PIC<CTRL-J>
  12. 80  HGR2 : REM (REVEALS & CLEARS PAGE 2)
  13. 90  PRINT  CHR$(4);"BLOAD COLOR CHART,A$4000": REM (LOADS PICTURE INTO PAGE 2)
  14. 95  REM <CTRL-J><CTRL-J>SWITCH FROM PAGE TO PAGE<CTRL-J>
  15. 100  GOSUB 160
  16. 110  POKE  -16304,0: REM (VIEW GRAPHICS SCREEN)
  17. 120  POKE  -16300,0: GOSUB 160: REM (VIEW PAGE 1)
  18. 130  POKE  -16299,0: GOSUB 160: REM (VIEW PAGE 2)
  19. 140  TEXT : GOSUB 160: REM (VIEW TEXT SCREEN)
  20. 150  GOTO 110
  21. 155  REM <CTRL-J><CTRL-J>PAUSE<CTRL-J>
  22. 160  FOR X = 1 TO 1000: NEXT : RETURN : REM (SMALLER NUMBER MAKES FASTER PAGE SWITCHES)
  23. 999  REM <CTRL-J><CTRL-J>EXPLANATION<CTRL-J>
  24. 1000  TEXT : HOME 
  25. 1010  INVERSE : PRINT : HTAB 4: PRINT " LIST THIS PROGRAM TO LEARN.": NORMAL : PRINT 
  26. 1020  PRINT "   REMEMBER, YOU HAVE TO DO 2 THINGS TO    DISPLAY A PICTURE FROM AN APPLESOFT     PROGRAM. DO THEM IN EITHER ORDER.                           ------ -----"
  27. 1040  PRINT "-> GET THE PICTURE IN MEMORY BY BLOADING   IT FROM DISK, OR BY DRAWING IT WITH     ALPHA PLOT OR HPLOT COMMANDS.           IMPORTANT: YOU NEVER BRUN A PICTURE.                   ----- ----"
  28. 1060  PRINT "-> REVEAL THE HI-RES SCREEN THAT CON-      TAINS (OR WILL CONTAIN) THE PICTURE.": PRINT 
  29. 1070  INVERSE : HTAB 4: PRINT " TO LOAD A HI-RES PICTURE:": NORMAL : PRINT "   BLOAD PICTURE,A$2000 (ONTO PAGE 1)   OR BLOAD PICTURE,A$4000 (ONTO PAGE 2)"
  30. 1081  PRINT "OR BLOAD PICTURE (ONTO THE PAGE FROM                     WHICH IT WAS BSAVED)": PRINT 
  31. 1100  INVERSE : HTAB 4: PRINT " TO SAVE A HI-RES PICTURE:": NORMAL : PRINT "   BSAVE NAME,A$2000,L$2000 (PAGE 1)    OR BSAVE NAME,A$4000,L$2000 (PAGE 2)";
  32. 1150  INVERSE : VTAB 8: HTAB 1: PRINT " 1": VTAB 13: PRINT " 2": NORMAL 
  33. 1200  VTAB 1: END 
  34. 5000  REM <CTRL-J><CTRL-J>UNSCRUNCH DEMO<CTRL-J>
  35. 5010  HOME : TEXT : HGR 
  36. 5020 D$ =  CHR$(4): PRINT D$;"BLOAD SCRUNCH": REM AT LOCATION 25000 AUTOMATICALLY
  37. 5030  PRINT D$;"BLOAD BBROS LOGO SCRUNCHED,A$4000": REM ONTO PAGE 2
  38. 5040  CALL 25003: REM UNSCRUNCHES PICTURE FROM PAGE 2 ONTO PAGE 1.
  39. 5050  REM TO SCRUNCH A PICTURE, SEE THE ALPHA PLOT INSTRUCTION MANUAL.
  40. 10000  REM CONFUSED? SO WERE WE WHEN WE FIRST ENCOUNTERED ALL THIS STUFF. REMEMBER, "YOU ONLY CAN LEARN WHAT YOU ALREADY HALF KNOW." KEEP TRYING!